@echo off
rem Tagesdatum formatieren und Übergabe an drei Variablen: Jahr, Monat und Tag.
set JJJJ=%date:~-4%
set MM=%date:~-7,2%
set TT=%date:~-10,2%
rem Zielordner mit einem Unterordner im Tagesdatumformat (JJJJ-MM-TT) zusammensetzen.
set destfolder=.\Zielordner\%JJJJ%-%MM%-%TT%
rem Dateiname der log-Datei festlegen.
set log=%destfolder%.log
rem Ausgabe in die log-Datei starten (Datei wird ggf. überschrieben).
echo Start %date% %time% > %log%

rem Kopieren aller Dateien vom Quell- zum Zielordner mit den Optionen:
rem /S Kopiert Ordner und Unterordner außer leeren Ordnern
rem /F Während des Kopiervorgangs den komletten Quell- und Zieldateinamen anzeigen
rem /H Versteckte- und Systemdateien kopieren
rem /K Dateiattribute kopieren
rem /Y Dateien ohne Rückfrage überschreiben
rem Die Dateinamen werden an die log-Datei angehängt.
xcopy "\\Server4711\c$\Programme\Quellordner\*.*" "%destfolder%\*.*" /S /F /H /K /Y >> %log%

rem Die zuvor kopierten Dateien und Ordner in eine zip-Datei komprimieren:
rem 7-zip exe-Datei im selben Ordner wie die bat-Datei starten.
rem Alle Dateinamen an die log-Datei anfügen.
rem Der ErrorLevel gibt Auskunft, ob die Operation erfolgreich war.
7za a %destfolder%.zip %destfolder%\* >> %log%
if ERRORLEVEL 0 goto CleanUp
if ERRORLEVEL 1 echo Warnung - Eventuell sind Dateien bereits in Benutzung >> %log%
if ERRORLEVEL 2 echo Fataler Fehler >> %log%
if ERRORLEVEL 7 echo Ungültige Kommandozeilenparameter >> %log%
if ERRORLEVEL 8 echo Nicht genug Speicher vorhanden >> %log%
if ERRORLEVEL 255 echo Abbruch durch Anwender >> %log%
echo Terminated >> %log%
echo End %date% %time% >> %log%
goto End

:CleanUp
rem Der Vorgang der Komprimierung war erfolgreich.
rem Alle Dateien im Unterordner löschen, dann alle zugehörigen Ordner.
del /q /f /s %destfolder%\*.*
rd /q /s %destfolder%
echo End %date% %time% >> %log%
rem Danach die log-Datei in die zip-Datei übernehmen.
7za a %destfolder%.zip %log%
rem Zuletzt die log-Datei löschen.
del /q %log%

:End
rem Hauptspeicher nicht vergessen.
set JJJJ=
set MM=
set TT=
set folder=
set log=